Add bookmarking functions

1 files changed, 54 insertions, 0 deletions

diff --git a/conf.d/99-bookmarks.zsh b/conf.d/99-bookmarks.zsh
new file mode 100644
index 0000000..58bd29a
--- /dev/null
+++ b/conf.d/99-bookmarks.zsh
@@ -0,0 +1,54 @@
+export MARKPATH=$HOME/.local/zsh/marks
+mkdir -p "$MARKPATH"
+
+j() {
+  cd -P "$MARKPATH/$1" 2>/dev/null || { echo "No such mark: $1"; return 1 }
+}
+
+mc() {
+	if [[ ( $# == 0 ) || ( "$1" == "." ) ]]; then
+		MARK=$(basename "$PWD")
+	else
+		MARK="$1"
+	fi
+	if read -q \?"Mark $PWD as ${MARK}? (y/n) "; then
+		mkdir -p "$MARKPATH"; ln -s "$PWD" "$MARKPATH/$MARK"
+	fi
+}
+
+md() {
+	rm -i "$MARKPATH/$1"
+}
+
+ml() {
+	for link in $MARKPATH/*(@); do
+		local markname="$fg[cyan]${link:t}$reset_color"
+		local markpath="$fg[blue]$(readlink $link)$reset_color"
+		printf "%s\t" $markname
+		printf "-> %s \t\n" $markpath
+	done
+}
+
+ms() {
+  j $(ml | fzf --ansi | awk '{print $1}')
+}
+
+_completemarks() {
+	if [[ $(ls "${MARKPATH}" | wc -l) -gt 1 ]]; then
+		reply=($(ls $MARKPATH/**/*(-) | grep : | sed -E 's/(.*)\/([_a-zA-Z0-9\.\-]*):$/\2/g'))
+	else
+		if readlink -e "${MARKPATH}"/* &>/dev/null; then
+			reply=($(ls "${MARKPATH}"))
+		fi
+	fi
+}
+compctl -K _completemarks j
+compctl -K _completemarks um
+
+_mark_expansion() {
+	setopt extendedglob
+	autoload -U modify-current-argument
+	modify-current-argument '$(readlink "$MARKPATH/$ARG")'
+}
+zle -N _mark_expansion
+bindkey "^g" _mark_expansion